AutoHotKey Scripts @ 7bit

左手だけで入力 "RibbitPad"

雑多なスクリプト

自分で使っているAutoHotKey(AHK)のちょっと便利なスクリプトです。1.0.45.02用。

AutoHotKeyを流行らせるページを使わせて貰っています。大変有用なサイトです。

#InstallKeybdHook
#UseHook

を書かないと動かない物があります。(リマップなど)

F6で日付時刻挿入

アホみたいに単純ですが、意外とよく使います。

; Alt+F6 (例:20051224-0347)
; Ctrl+F6 (例:20051224-03:48)
; Alt+Ctrl+F6 (例:2005 12/24 03:48)
!F6::
	Send, %A_YYYY%%A_MM%%A_DD%-%A_Hour%%A_Min%
return
^F6::
	Send, %A_YYYY%%A_MM%%A_DD%-%A_Hour%:%A_Min%
return
!^F6::
	Send, %A_YYYY% %A_MM%/%A_DD% %A_Hour%:%A_Min%
return

F11でアクティブウィンドウの最大化トグル

Alt+Returnにしたい場合は!Return

F11::
  WinGet, State, MinMax, A
  if State != 0
    WinRestore, A
  else
    WinMaximize, A
  return

同じウィンドウクラスのウィンドウを切り替える(Alt+Ctrl+Tab)

こちらを参考にしています。タブ切り替えのためだけにPedorosa使っている場合も、PuTTYに戻れます。

!^Tab::
  WinGetClass, className, A
  WinActivateBottom, ahk_class %className%
  return

IMEのオンオフをCtrl+Spaceでトグル(半角全角キーに変換)

英語配列のキーボードでAlt+`が面倒な場合に。ただこれを使っているとたまにCtrl Lockのような状態になって、打ったキーが全部C修飾されてとんでもない事態が引き起こされることもあります。

^Space::Send, {vkF3sc029}

HappyHackingKeyboard(HHKB)のR-◇をR-Ctrlに変換

HHKモードだと右◇は死んでいるようなので。

vkFFsc079::RCtrl

Lite Ext.モードにして、右◇をWinとして使うのも良さそう。

VimでEsc/^[/^CにあわせてIMEも切る

挿入モードから抜けるとき、IMEがONのままだと困るのでESC/^[/^Cに先だってIMEをOFFにします。以下はATOK20で「Ctrl-無変換(vk1Dsc07B)」をIMEのOFFに割り当てた場合。

#IfWinActive ahk_class Vim
; EscでIMEもオフ(無変換vk1Dsc07B, 変換vk1Csc079)
Esc::Send,{CtrlDown}{vk1Dsc07B}{CtrlUp}{Esc}
^[::Send,{CtrlDown}{vk1Dsc07B}[{CtrlUp}
^C::Send,{CtrlDown}{vk1Dsc07B}C{CtrlUp}
#IfWinActive

PuTTY上でVimを使う際にも同じ問題が発生するので、ahk_class PuTTYの分も書いておくと良いでしょう。

同様にVimperatorも

FirefoxのVimlikeアドオン、Vimperatorでは入力エリアで^[がEscにならなかったり、^Jが効かなかったりするので修正ッ

#IfWinActive ahk_class MozillaUIWindowClass
; EscでIMEもオフ(無変換vk1Dsc07B, 変換vk1Csc079)
; C-JでReturn, C-[でEsc
Esc::Send,{CtrlDown}{vk1Dsc07B}{CtrlUp}{Esc}
^[::Send,{CtrlDown}{vk1Dsc07B}{CtrlUp}{Esc}  ; [を置換
^C::Send,{CtrlDown}{vk1Dsc07B}C{CtrlUp}
^J::Send,{Return}
#IfWinActive

Winキーがないけど「デスクトップの表示」したい

; LAlt+Z -> Show Desktop
<!Z::Send, #d

単独のWinキーでスタートメニューを表示しない

RWin::return
RWin & RWin::return
LWin::return
LWin & LWin::return

表示したければCtrl-Esc

ウィンドウの移動・サイズ変更

Win + カーソルでウィンドウ移動、Win+Shift+カーソルでウィンドウサイズ変更する。

; --------------------------------------------------
; Window Move
WinMoveStep(XD,YD) {
	WinGet,win_id,ID,A
	WinGetPos,x,y,,,ahk_id %win_id%
	Step := 24
	x := x + (XD * Step)
	y := y + (YD * Step)
	WinMove,ahk_id %win_id%,,%x%,%y%
	return
}
#Left::WinMoveStep(-1,0)
#Right::WinMoveStep(1,0)
#Up::WinMoveStep(0,-1)
#Down::WinMoveStep(0,1)

; --------------------------------------------------
; Window Size
WinSizeStep(XD,YD) {
	WinGet,win_id,ID,A
	WinGetPos,,,w,h,ahk_id %win_id%
	Step := 24
	w := w + (XD * Step)
	h := h + (YD * Step)
	WinMove,ahk_id %win_id%,,,,%w%,%h%
	return
}
+#Left::WinSizeStep(-1,0)
+#Right::WinSizeStep(1,0)
+#Up::WinSizeStep(0,-1)
+#Down::WinSizeStep(0,1)

US QWERTY配列キーボードをDvorak化(Ctrl透過)

手許のHHKB Professional用に、英語キーボードの配列をQWERTYからDvorakに変更するスクリプトを書いてみました。Ctrl修飾は文字よりも位置が重要であることが多いので、透過します。(例えばCtrl+XCVがCtrl+QJKに変換されません)

Ctrl+Alt+A -> Toggle Mode
Ctrl+Alt+D -> Dvorak Mode
Ctrl+Alt+F -> QWERTY Mode

dvorak_20080430.zip: v1.10 .ahk
dvorak_exe_20080430.zip: v1.10 .exe
dvorak_100.zip: v1.00 .ahkファイルと.exeのセット

JaneDoe ViewでVim風キーバインド

#IfWinActive ahk_class TMainWnd
r::^r

j::WheelDown
k::WheelUp


h::^PgUp
l::^PgDn
$+g::Send,{Blind}{ShiftUp}{CtrlDown}{End}{CtrlUp}{ShiftDown}

$g::^Home
#IfWinActive

rで更新、jkで上下、hlでタブ選択、gで先頭、Gで末尾

Foxit ReaderでVim風キーバインド


#IfWinActive ahk_class Afx:400000:8:10017:0:12805d1
j::Down
k::Up
h::Left
l::Right
$+g::Send,{Blind}{ShiftUp}{CtrlDown}{End}{CtrlUp}{ShiftDown}
$g::^Home
#IfWinActive

jkで上下、hlでページ上下、gで先頭、Gで末尾

7bit

最近の更新

関連

その他いろいろ